読者です 読者をやめる 読者になる 読者になる

計算機プログラムの構造と解釈 第二版 pp216-228 写経

4章に入りました。
4章いきなり大変ですね。本当に大変です。
冒頭から12ページ分の写経を行わないと、プログラムが動きません。
216ページの頭から、228ページの半ばまで。


しかもただ写経しただけでは動かなくていくつか注意しないと行けないです。
ちなみに僕はgouche 0.9なので他の環境は知らないです。


注意するところ。

  • trueとfalse (goucheでは#tと#fです書き換えるか、define)
  • p227の注釈のコード(これも必要)
  • p227の注釈のコードはapplyの定義より前に書く。(良く読めば当然)
  • applyとevalの定義の位置(教科書の順番だとダメ、applyをevalより先にかく、そうじゃないとプリミティブなapplyを呼んじゃう)
  • setup-environmentの定義より前にprimitive-procedure-names、primitive-procedure-objects、primitive-proceduresの定義を書く

はいこんな感じです。


適当に写経して「うがー」ってなったらコピペしてみてください。

;; -*- coding: utf-8 -*-
(define true #t)
(define false #f)


(define apply-in-underlying-scheme apply)

(define (apply procedure arguments)
  (cond ((primitive-procedure? procedure)
         (apply-primitive-procedure procedure arguments))
        ((compound-procedure? procedure)
         (eval-sequence
           (procedure-body procedure)
           (extend-environment
             (procedure-parameters procedure)
             arguments
             (procedure-environment procedure))))
        (else
          (error
            "Unknown procedure type -- APPLY" procedure))))

(define (eval exp env)
  (cond ((self-evaluating? exp) exp)
        ((variable? exp) (lookup-variable-value exp env))
        ((quoted? exp) (text-of-quotation exp))
        ((assignment? exp) (eval-assignment exp env))
        ((definition? exp) (eval-definition exp env))
        ((if? exp) (eval-if exp env))
        ((lambda? exp)
         (make-procedure (lambda-parameters exp)
                         (lambda-body exp)
                         env))
        ((begin? exp) 
         (eval-sequence (begin-actions exp) env))
        ((cond? exp) (eval (cond->if exp) env))
        ;;4.6
;        ((let? exp) (eval (let->combination exp) env))
        ;;4.7
;        ((let*? exp) (eval (let*->nested-lets exp) env))
        ((application? exp)
         (apply (eval (operator exp) env)
                (list-of-values (operands exp) env)))
        (else
          (error "Unknown expression type -- EVAL" exp))))



(define (list-of-values exps env)
  (if (no-operands? exps)
    '()
    (cons (eval (first-operand exps) env)
          (list-of-values (rest-operands exps) env))))


;; eval
(define (eval-if exp env)
  (if (true? (eval (if-predicate exp) env))
    (eval (if-consequent exp) env)
    (eval (if-alternative exp) env)))

(define (eval-sequence exps env)
  (cond ((last-exp? exps) (eval (first-exp exps) env))
        (else (eval (first-exp exps) env)
              (eval-sequence (rest-exps exps) env))))

(define (eval-assignment exp env)
  (set-variable-value! (assignment-variable exp)
                       (eval (assignment-value exp) env)
                       env)
  'ok)

(define (eval-definition exp env)
  (define-variable! (definition-variable exp)
                    (eval (definition-value exp) env)
                    env)
  'ok)


;;4.6 let
;(define (let? exp) (tagged-list? exp 'let))
;
;(define (let-clauses exp) (cdr exp))
;
;(define (let-bindings clauses) (car clauses))
;
;(define (let-body clauses) (cdr clauses))
;
;(define (let->combination exp)
;  (expand-let-clauses (let-clauses exp)))
;
;
;(define (expand-let-clauses clauses)
;  (if (null? (let-bindings clauses))
;    '()
;    (cons (make-lambda (map car (let-bindings clauses)) (let-body clauses))
;          (map cadr (let-bindings clauses)))))


;;4.7 let*
;(define (let*? exp) (tagged-list? exp 'let*))
;
;(define (let*-clauses exp) (cdr exp))
;
;(define (let*-bindings clauses) (car clauses))
;
;(define (let*-body clauses) (cadr clauses))
;
;(define (make-let* defs body)
;  (list 'let defs body))
;
;(define (let*->nested-lets exp)
;  (if (null? exp)
;      'false
;      (let ((clauses (let*-clauses exp)))
;           (let ((bindings (let*-bindings clauses))
;                 (body (let*-body clauses)))
;                (define (iter rest-bindings)
;                  (if (null? rest-bindings)
;                      body
;                      (make-let* (list (car rest-bindings))
;                                (iter (cdr rest-bindings)))))
;           (iter bindings)))))


;;;;;;;;;;;;;;
;; 式の表現
;;;;;;;;;;;;;;

;; 自己評価式
(define (self-evaluating? exp)
  (cond ((number? exp) true)
        ((string? exp) true)
        (else false)))

;; 変数は記号で評価
(define (variable? exp) (symbol? exp))


;; クォート式
(define (quoted? exp)
  (tagged-list? exp 'quote))

(define (text-of-quotation exp) (cadr exp))

(define (tagged-list? exp tag)
  (if (pair? exp)
    (eq? (car exp) tag)
    false))


;; 代入(set!)
(define (assignment? exp)
  (tagged-list? exp 'set!))

(define (assignment-variable exp) (cadr exp))

(define (assignment-value exp) (caddr exp))


;; 定義(define)
(define (definition? exp)
  (tagged-list? exp 'define))

(define (definition-variable exp)
  (if (symbol? (cadr exp))
    (cadr exp)
    (caadr exp)))

(define (definition-value exp)
  (if (symbol? (cadr exp))
    (caddr exp)
    (make-lambda (cdadr exp)   ; 仮パラメタ
                 (cddr exp)))) ; 本体


;; lambda
(define (lambda? exp) (tagged-list? exp 'lambda))

(define (lambda-parameters exp) (cadr exp))

(define (lambda-body exp) (cddr exp))

(define (make-lambda parameters body)
  (cons 'lambda (cons parameters body)))


;; 条件式(if)
(define (if? exp) (tagged-list? exp 'if))

(define (if-predicate exp) (cadr exp))

(define (if-consequent exp) (caddr exp))

(define (if-alternative exp)
  (if (not (null? (cdddr exp)))
    (cadddr exp)
    'false))

(define (make-if predicate consequent alternative)
  (list 'if predicate consequent alternative))


;; begin
(define (begin? exp) (tagged-list? exp 'begin))

(define (begin-actions exp) (cdr exp))

(define (last-exp? seq) (null? (cdr seq)))

(define (first-exp seq) (car seq))

(define (rest-exps seq) (cdr seq))

(define (sequence->exp seq)
  (cond ((null? seq) seq)
        ((last-exp? seq) (first-exp seq))
        (else (make-begin seq))))

(define (make-begin seq) (cons 'begin seq))


;; 手続き作用
(define (application? exp) (pair? exp))

(define (operator exp) (car exp))

(define (operands exp) (cdr exp))

(define (no-operands? ops) (null? ops))

(define (first-operand ops) (car ops))

(define (rest-operands ops) (cdr ops))



;;;;;;;;;;;;;;;;;
;; 導出された式
;;;;;;;;;;;;;;;;;
(define (cond? exp) (tagged-list? exp 'cond))

(define (cond-clauses exp) (cdr exp))

(define (cond-else-clause? clause)
  (eq? (cond-predicate clause) 'else))

(define (cond-predicate clause) (car clause))

(define (cond-actions clause) (cdr clause))

(define (cond->if exp)
  (expand-clauses (cond-clauses exp)))

(define (expand-clauses clauses)
  (if (null? clauses)
    'false                          ; no else clause
    (let ((first (car clauses))
          (rest (cdr clauses)))
      (if (cond-else-clause? first)
        (if (null? rest)
          (sequence->exp (cond-actions first))
          (error "ELSE clause isn't last -- COND->IF"
                 clauses))
        (make-if (cond-predicate first)
                 (sequence->exp (cond-actions first))
                 (expand-clauses rest))))))


;; 4.5
;(define (expand-clauses clauses)
;  (if (null? clauses)
;    #f
;    (let ((first (car clauses))
;          (rest (cdr clauses)))
;      (if (cond-else-clause? first)
;        (if (null? rest)
;          (sequence->exp (cond-actions first))
;          (error "ELSE clause isn't last -- COND->IF"
;                 clauses))
;        (make-if (cond-predicate first)
;                 (let ((action (cond-actions first))
;                       (predicate (cond-predicate first)))
;                   (if (eq? (car action) '=>)
;                     (list (cadr action) predicate)
;                     (sequence->exp action)))
;                 (expand-clauses rest))))))


;;;;;;;;;;;;;;;;;;;;;;
;; 評価器のデータ構造
;;;;;;;;;;;;;;;;;;;;;;

;; 述語のテスト
(define (true? x)
  (not (eq? x false)))

(define (false? x)
  (eq? x false))


;; 手続きの表現
(define (make-procedure parameters body env)
  (list 'procedure parameters body env))

(define (compound-procedure? p)
  (tagged-list? p 'procedure))

(define (procedure-parameters p) (cadr p))

(define (procedure-body p) (caddr p))

(define (procedure-environment p) (cadddr p))


;; 環境に対する評価
(define (enclosing-environment env) (cdr env))
(define (first-frame env) (car env))
(define the-empty-environment '())

(define (make-frame variables values)
  (cons variables values))
(define (frame-variables frame) (car frame))
(define (frame-values frame) (cdr frame))
(define (add-binding-to-frame! var val frame)
  (set-car! frame (cons var (car frame)))
  (set-cdr! frame (cons val (cdr frame))))

(define (extend-environment vars vals base-env)
  (if (= (length vars) (length vals))
    (cons (make-frame vars vals) base-env)
    (if (< (length vars) (length vals))
      (error "Too many arguments supplied" vars vals)
      (error "Too few arguments supplied" vars vals))))

(define (lookup-variable-value var env)
  (define (env-loop env)
    (define (scan vars vals)
      (cond ((null? vars)
             (env-loop (enclosing-environment env)))
            ((eq? var (car vars))
             (car vals))
            (else (scan (cdr vars) (cdr vals)))))
    (if (eq? env the-empty-environment)
      (error "Unbound variable" var)
      (let ((frame (first-frame env)))
        (scan (frame-variables frame)
              (frame-values frame)))))
  (env-loop env))

(define (set-variable-value! var val env)
  (define (env-loop env)
    (define (scan vars vals)
      (cond ((null? vars)
             (env-loop (enclosing-environment env)))
            ((eq? var (car vars))
             (set-car! vals val))
            (else (scan (cdr vars) (cdr vals)))))
    (if (eq? env the-empty-environment)
      (error "Unbound variable -- SET!" var)
      (let ((frame (first-frame env)))
        (scan (frame-variables frame)
              (frame-values frame)))))
  (env-loop env))

(define (define-variable! var val env)
  (let ((frame (first-frame env)))
    (define (scan vars vals)
      (cond ((null? vars)
             (add-binding-to-frame! var val frame))
            ((eq? var (car vars))
             (set-car! vals val))
            (else (scan (cdr vars) (cdr vals)))))
    (scan (frame-variables frame)
          (frame-values frame))))


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 評価器をプログラムとして走らせる
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

(define (primitive-procedure-names)
  (map car
       primitive-procedures))

(define (primitive-procedure-objects)
  (map (lambda (proc) (list 'primitive (cadr proc)))
       primitive-procedures))

(define primitive-procedures
  (list (list 'car car)
        (list 'cdr cdr)
        (list 'cons cons)
        (list 'null? null?)
        (list '+ +)
        (list '- -) ;; 4.8
        (list '* *)
        (list 'assoc assoc) ;; 4.5
        (list '= =) ;; 4.8
        (list 'print print)
        ;  <基本手続きが続く>
        ))

(define (setup-environment)
  (let ((initial-env
          (extend-environment (primitive-procedure-names)
                              (primitive-procedure-objects)
                              the-empty-environment)))
    (define-variable! 'true true initial-env)
    (define-variable! 'false false initial-env)
    initial-env))

(define the-global-environment (setup-environment))

(define (primitive-procedure? proc)
  (tagged-list? proc 'primitive))

(define (primitive-implementation proc) (cadr proc))


(define (apply-primitive-procedure proc args)
  (apply-in-underlying-scheme
    (primitive-implementation proc) args))


(define input-prompt ";;; M-Eval input:")

(define output-prompt ";;; M-Eval value:")

(define (driver-loop)
  (prompt-for-input input-prompt)
  (let ((input (read)))
    (let ((output (eval input the-global-environment)))
      (announce-output output-prompt)
      (user-print output)))
  (driver-loop))

(define (prompt-for-input string)
  (newline) (newline) (display string) (newline))

(define (announce-output string)
  (newline) (display string) (newline))

(define (user-print object)
  (if (compound-procedure? object)
    (display (list 'compound-procedure
                   (procedure-parameters object)
                   (procedure-body object)
                   '<procedure-env>))
    (display object)))


;(define the-global-environment (setup-environment))
;(driver-loop)

どうすか。