計算機プログラムの構造と解釈 第二版 P88 問題2.57

これは、要はaugendとmultiplicandの定義を変更して、

(+ 1 2 x)

(* 1 2 x)

みたいな扱いも出来るように仕様っていうこと。

で、さらにいうと

(augend '(+ 1 2 x))

を実行すると

(+ 2 x)

が返るようにしてやれば良い。

consの定義を考えてやれば、三項目以降が存在するかどうか調べるには
null?を使えばよいから、、、

実装

#!/usr/local/bin/gosh
;; -*- coding: utf-8 -*-

(use ggc.debug.trace)
(use math.mt-random)


;変数は記号とする、基本手続きsymbol?で識別できる:
(define (variable? x) (symbol? x))

;二つの変数はそれを表現している記号がeq?なら同じである:
(define (same-variable? v1 v2)
  (and (variable? v1) (variable? v2) (eq? v1 v2)))

;和は最初の要素が記号+である:
(define (sum? x)
  (and (pair? x) (eq? (car x) '+)))

;加数は和のリストの第二項である:
(define (addend s)
  (cadr s))

;被加数は和のリストの第三項である:
;問題2.57で修正
(define (augend s)
  (if (null? (cdddr s)) (caddr s)
    (cons '+ (cddr s))))

;積は最初の要素が記号*であるリストである:
(define (product? x)
  (and (pair? x) (eq? (car x) '*)))

;乗数は積のリストの第二項である:
(define (multiplier p)
  (cadr p))

;被乗数は積のリストの第三項である:
;問題2.57で修正
(define (multiplicand p)
  (if (null? (cdddr p)) (caddr p)
    (cons '* (cddr p))))

;簡約版make-sum
(define (make-sum a1 a2)
  (cond ((=number? a1 0) a2)
        ((=number? a2 0) a1)
        ((and (number? a1) (number? a2)) (+ a1 a2))
        (else (list '+ a1 a2))))


(define (=number? exp num)
  (and (number? exp) (= exp num)))

;完訳版make-product
(define (make-product m1 m2)
  (cond ((or (=number? m1 0) (=number? m2 0)) 0)
        ((=number? m1 1) m2)
        ((=number? m2 1) m1)
        ((and (number? m1) (number? m2)) (* m1 m2))
        (else (list '* m1 m2))))


;べき乗は最初の要素が記号**であるリストである:
(define (exponentiation? x)
  (and (pair? x) (eq? (car x) '**)))

;基数はべき乗のリストの第二項である。
(define (base x)
  (cadr x))

;乗数はべき乗のリストの第三項である。
(define (exponent x)
  (caddr x))


(define (make-exponentiation b e)
  (cond ((=number? b 0) 0)
        ((=number? e 1) b)
        ((=number? e 0) 1)
        ((and (number? b) (number? e)) (expt b e))
        (else (list '** b e))))


;;微分規則
(define (deriv exp var)
  (cond ((number? exp) 0)
        ((variable? exp)
         (if (same-variable? exp var) 1 0))
        ((sum? exp)
         (make-sum (deriv (addend exp) var)
                   (deriv (augend exp) var)))
        ((product? exp)
         (make-sum
           (make-product (multiplier exp)
                         (deriv (multiplicand exp) var))
           (make-product (deriv (multiplier exp) var)
                         (multiplicand exp))))
        ;ここを追記
        ((exponentiation? exp)
         (make-product (exponent exp)
                       (make-product
                         (make-exponentiation (base exp) (- (exponent exp) 1))
                         (deriv (base exp) var))))
        (else
          (error "unknown expression type -- DERIV" exp))))

(define test '(* 3 4 5))
(define test2 '(* 3 4))
;; main
(define (main args)

  (display "(deriv '(* (* x y) (+ x 3)) 'x)")
  (display (deriv '(* (* x y) (+ x 3)) 'x))
  (newline)

  (display "(deriv '(* x y (+ x 3)) 'x): ")
  (display (deriv '(* x y (+ x 3)) 'x))
  (newline)

  0)

実行

(deriv '(* (* x y) (+ x 3)) 'x)(+ (* x y) (* y (+ x 3)))
(deriv '(* x y (+ x 3)) 'x): (+ (* x y) (* y (+ x 3)))

同じ意味の違う式だが、ちゃんと同じように扱われた。